excelدا كىملىك نومۇرىغا ئائىت فۇنكسىيە جەۋھىرى

tamqi

كىملىك نومۇرى خاتا كىرگۈزۈلسە ئۇچۇر بىرىش

=IF(ISERROR(IF(A3<>"",TEXT((LEN(A3)=15)*19&MID(A3,7,6+(LEN(A3)=18)*2),"#-00-00")+0,)),"身份证号错误",IF(A3<>"",TEXT((LEN(A3)=15)*19&MID(A3,7,6+(LEN(A3)=18)*2),"#-00-00")+0,))

=IF(ISERROR(IF(A2<>"",TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00")+0,)),"cuowu",IF(A2<>"",TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00")+0,))

ماكرو

Function GetBrithdayFromID(strID As String) As String
GetBrithdayFromID = Mid(strID, 7, 4) & "-" & Mid(strID, 11, 2) & "-" & Mid(strID, 13, 2)




تۇغۇلغان ۋاقىتنى ھىساپلاش فورمۇلاسى

=IF(A2<>"",TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00")+0,)

جىنسىنى ھىساپلاش  



=IF(A2<>"",IF(MOD(RIGHT(LEFT(A2,17)),2),"男","女"),)

ياش ھىساپلاش

=IF(A2<>"",DATEDIF(TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00"),TODAY(),"y"),)

ھەممىنى 18 خانە قىلىش

=IF(LEN(A2)=15,REPLACE(A2,7,,19)&MID("10X98765432",MOD(SUM(MID(REPLACE(A2,7,,19),ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1),A2)

دىققەت: بۇنىڭدا فۇنكسىيەنى كىرگۈزۈپ بولۇپ ئۇنى تاللاپ ctrl+shift+enterنى باسسىڭىز {} قوشۇلىدۇ.

پىنسىيە يېشى

=IF(A2<>"",EDATE(TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00"),660+MOD(RIGHT(LEFT(A2,17)),2)*60),)

كىملىكنى تەكشۈرۈش

=OR(LEN(A2)=15,IF(LEN(A2)=18,MID("10X98765432",MOD(SUM(MID(A2,ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1)=RIGHT(A2)))

دىققەت: بۇنىڭدا فۇنكسىيەنى كىرگۈزۈپ بولۇپ ئۇنى تاللاپ ctrl+shift+enterنى باسسىڭىز {} قوشۇلىدۇ.

تۇرۇشلۇق ئۆلكە نامى

=IF(A2<>"",VLOOKUP(LEFT(A2,2),data,2,),)

دىققەت؛بۇنىڭدىكى data باشقا جەدۋەلدە تەييارلىۋالغان ئۆلكە نامى تىزىملىك دائىرىسىنى كۆرسىتىدۇ.

تۇرۇشلۇق شەھەر نامى

=IF(A2<>"",VLOOKUP(LEFT(A2,6),data,2,))

دىققەت؛بۇنىڭدىكى data باشقا جەدۋەلدە تەييارلىۋالغان ئۆلكە نامى تىزىملىك دائىرىسىنى كۆرسىتىدۇ.

A2 ئورۇندا كىملىك نومۇرى بار دەپ پەرەز قىلساق، B2 ئورۇنغا يىل، ئاي، كۈننى ئېلىش ئۈچۈن:
(1)B2 نى تاللايمىز.    (2) تۆۋەندىكى پورمۇلانى كىرگۈزىمىز:
=MID(A2,13,2)&"كۈن"&MID(A2,11,2)&"ئاي"&MID(A2,7,4)&"يىل"

پورمۇلانى كىرگۈزۈپ بولغاندىن كىيىن Enter كونۇپكىسىنى بىسىۋەتسەك  B2 ئورۇنغا يىل، ئاي، كۈن كىرگۈزىلىدۇ.
بۇ يەردە بىز ئىشلەتكەن  mid فونكىسيەنىڭ رولى بولسا بەلگىلەنگەن كاتەكتىكى بەلگىلەنگەن ئورۇندىن بەلگىلەنگەن ئۇزۇنلۇقتىكى قىممەتنى ئېلىش. مەسىلەن MID(A2,7,4)  بولسا  A2 ئورۇندىكى 7- ئورۇندىن (خانىدىن) باشلاپ 4  قىممەت ئېلىشتىن ئىبارەت

بايقاش

يارايسىز تامچى ئەپەندىم... مۇشۇنداق excelبىلىملىرى بىلەن تەمىنلەپ تۇرۇڭ..

sargardan

قولىڭىزغا دەرت بەرمىسۇن...

sardar

تامچى ئەپەندىم... مۇشۇنداق تىمىلار بىلەن تەمىنلىشىڭىزنى ئۈمۈد قىلىمەن...