excel دا كىملىك نومۇرىغا ئائىت فۇنكسىيە جەۋھىرى

Intil · ۋاقتى: 2010-7-24 15:52:04

تۇغۇلغان ۋاقىتنى ھىساپلاش فورمۇلاسى

=IF(A2<>"",TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00")+0,)

مەزمۇننى كۆچۈرۈۋېلىش

جىنسىنى ھىساپلاش

=IF(A2<>"",IF(MOD(RIGHT(LEFT(A2,17)),2),"男","女"),)

مەزمۇننى كۆچۈرۈۋېلىش

ياش ھىساپلاش

=IF(A2<>"",DATEDIF(TEXT((LEN(A2)=15)*19&MID(A2,7,6+(LEN(A2)=18)*2),"#-00-00"),TODAY(),"y"),)

مەزمۇننى كۆچۈرۈۋېلىش

ھەممىنى 18 خانە قىلىش

=IF(LEN(A2)=15,REPLACE(A2,7,,19)&MID("10X98765432",MOD(SUM(MID(REPLACE(A2,7,,19),ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1),A2

مەزمۇننى كۆچۈرۈۋېلىش

دىققەت: بۇنىڭدا فۇنكسىيەنى كىرگۈزۈپ بولۇپ ئۇنى تاللاپ ctrl+shift+enterنى باسسىڭىز {} قوشۇلىدۇ.

bostan305 · ۋاقتى: 2012-1-6 17:57:29

پايدىلنىش قىممىتى يۇقىرى ، كۆپ قوللىنىلىدۇ

Intil · ۋاقتى: 2010-7-31 18:49:18

تۇغۇلغان ئاي ، كۈنى

=IF(LEN(I29)=18,DATE(MID(I29,7,4),MID(I29,11,2),MID(I29,13,2)),DATE(MID(I29,7,2),MID(I29,9,2),MID(I29,11,2)))
UID

مەزمۇننى كۆچۈرۈۋېلىش

Intil · ۋاقتى: 2010-9-12 00:45:53

كىملىك نومۇرىنىڭ توغرا خاتالىقىغا ھۆكۈم قىلىش

=IF(OR(LEN(B1)=18,LEN(B1)=15),IF(LEN(B1)=18,IF(OR(MONTH(DATE(1*(MID(B1,7,4)),1*(MID(B1,11,2)),1*(MID(B1,13,2))))<>1*(MID(B1,11,2)),DAY(DATE(1*(MID(B1,7,4)),1*(MID(B1,11,2)),1*(MID(B1,13,2))))<>1*(MID(B1,13,2))),"月日错误",""),IF(LEN(B1)=15,IF(OR(MONTH(DATE(1*(MID(B1,7,2))+1900,1*(MID(B1,9,2)),1*(MID(B1,11,2))))<>1*(MID(B1,9,2)),DAY(DATE(1*(MID(B1,7,2))+1900,1*(MID(B1,9,2)),1*(MID(B1,11,2))))<>1*(MID(B1,11,2))),"月日错误",""))),"身份证位数不对")&IF(AND(LEN(B1)=18,1*MID(B1,7,4)>YEAR(TODAY())-6),"年份错误","")

مەزمۇننى كۆچۈرۈۋېلىش

Intil · ۋاقتى: 2010-9-12 00:49:22

كىملىك نومۇرى شەكلىگە ھۆكۈم قىلىش

=IF(OR(LEN(B1)=18,LEN(B1)=15),IF(LEN(B1)=18,IF(OR(MONTH(DATE(1*(MID(B1,7,4)),1*(MID(B1,11,2)),1*(MID(B1,13,2))))<>1*(MID(B1,11,2)),DAY(DATE(1*(MID(B1,7,4)),1*(MID(B1,11,2)),1*(MID(B1,13,2))))<>1*(MID(B1,13,2))),"月日错误",""),IF(LEN(B1)=15,IF(OR(MONTH(DATE(1*(MID(B1,7,2))+1900,1*(MID(B1,9,2)),1*(MID(B1,11,2))))<>1*(MID(B1,9,2)),DAY(DATE(1*(MID(B1,7,2))+1900,1*(MID(B1,9,2)),1*(MID(B1,11,2))))<>1*(MID(B1,11,2))),"月日错误",""))),"身份证位数不对")&IF(AND(LEN(B1)=18,1*MID(B1,7,4)>YEAR(TODAY())-6),"年份错误","")

مەزمۇننى كۆچۈرۈۋېلىش

Intil · ۋاقتى: 2010-9-24 12:48:31

قورامىغا يەتكەن-يەتمىگەنگە ھۆكۈم قىلىش
[FLIPH]C1单元格输入公式判断是否成年:
=IF(DATEDIF(TEXT(MID(A1,7,LEN(A1)/1.5-4),"#-00-00"),NOW(),"y")>=18,"成年人","未成年")

TEXT(MID(A1,7,LEN(A1)/1.5-4),"#-00-00")
这个也是根据字符长度返回身份证的数字来生成出生日期。
18返回: YYYYMMDD
18/1.5-4=8个字符
15返回:YYMMDD
15/1.5-4=6个字符

Text(,"#-00-00")
将数字变成日期形式的文本。

Datedif(生日,Now(),"Y")
返回生日距今天的年份。
********
不太明白楼主的意思，我的这个公式就是根据A1单元格的身份证来判断是否是成年人。如果身份证不在A1,你可以换成其他单元格。

另外如果你的意思是不是从现在判读是否成年而是一个固定的日期的话，可以这么修改:

假设D1是日期:2008-1-1

那么C1的公式是:
=IF(DATEDIF(TEXT(MID(A1,7,LEN(A1)/1.5-4),"#-00-00"),D1,"y")>=18,"成年人","未成年")

将公式中的Now()改为固定日期所在单元格的引用,也可直接写在上面:
=IF(DATEDIF(TEXT(MID(A1,7,LEN(A1)/1.5-4),"#-00-00"),"2008-1-1","y")>=18,"成年人","未成年") [/FLIPH]

Intil · ۋاقتى: 2010-10-7 22:06:36

654101196902012650 دىن تۇغۇلغان يىل ، ئاي، كۈننى ئېلىپ ئالدىغا 01342 نى قوشۇش.

="01342"&MID（A1,7,8）

مەزمۇننى كۆچۈرۈۋېلىش

Sezgurboy · ۋاقتى: 2010-10-18 11:23:45

1. كىملىك نومۇرىغا مۇناسىۋەتلىك بىلىملەر
ئېلگىرىكى كىملىك نومۇرلىرى 15 خانلىق بولۇپ، ھازىرقى كىملىك نومۇرلىرى 18 خانلىق. بىز بۇ كىملىك نومۇرلىرى ئارقىلىق شۇ بىر ئادەمگە مۇناسىۋەتلىك نۇرغۇن ئۇچۇرلارغا ئىگە بولالايمىز. يەنى:
15 خانىلىق كىملىك نومۇرى :
1-6 خانىگىچە بولغان نومۇرلار مەمۇرى رايۇن نومۇرىغا ۋەكىللىك قىلىدۇ؛7-8 خانلىرى تۇغۇلغان يىلىغا ۋەكىللىك قىلىدۇ؛ 9-10 خانىلىرى تۇغۇلغان ئاي ؛ 11-12 خانىلىرى تۇغۇلغان كۈنى؛ 13-15 خانلىرى رەت تەرتىۋى بولۇپ، تاق سان بولسا ئۇ كىشىنىڭ جىنسى ئەر، جۈپ سان بولسا ئايال ئىكەنلىكىنى بىلدۈرىدۇ.
18 خانلىق كىملىك نومۇرى :
1-6 خانىگىچە بولغان نومۇرلار مەمۇرى رايۇن نومۇرىغا ۋەكىللىك قىلىدۇ. 7-10 خانلىرى تۇغۇلغان يىلىغا ۋەكىللىك قىلىدۇ؛ 11-12 خانىلىرى تۇغۇلغان ئاي ؛ 13-14 خانىلىرى بولسا تۇغۇلغان كۈنى؛ 15-17 خانلىرى بولسا رەت تەرتىۋى بولۇپ، تاق سان بولسا ئەر، جۈپ سان بولسا ئايال ئىكەنلىكىنى بىلدۈرىدۇ. 18- خانىسى تەكشۈرۈش خانىسى ھىساپلىنىدۇ.
2. ئىشلىتىلگەن فونكىسيەلەر:
(1) . IF فونكىسيەسى . شەرتكە ئاساسەن نەتىجىنى چىقىرىپ بىرىدۇ. قاپلاپ ئىشلىتىشكە بولىدۇ.
(2) . CONCATENATE فونكىسيەسى . بىر قانچە ھەرپلەرنى بىرلەشتۈرۈپ چىقىرىپ بىرىدۇ.
(3) . MID فونكىسيەسى . تىكستلەر ئىچىدىكى بەلگىلەنگەن ئورۇندىن بەلگىلەنگەن ئۇزۇنلۇقتىكى ھەرپلەرنى ئۈزۈۋالىدۇ.
(4) . TODAY فونكىسيەسى . كومپىيۇتېرنىڭ نۆۋەتتىكى چىسلاسىنى چىقىرىپ بىرىدۇ.
(5) . MOD فونكىسيەسى. ئىككى ساننى بۆلگەندىكى قالدۇقنى تىپىش فونكىيەسى.
(6) . VALUE فونكىيسەسى . تىكست تىپىدىكى سانلارنى سانلىق مەلۇمات تىپىدىكى سانلارغا ئايلاندۇرىدۇ.
(7) . RIGHT فونكىسيەسى. بەلگىلەنگەن سان بويىچە ھەرپ-تىزمىسىنىڭ ئەڭ ئاخىرىدىكى بىر ياكى بىر نەچچە ھەرپلەرنى ئۈزۈپ ئېلىپ چىقىرىپ بىرىدۇ.
(8) . INT فونكىسيەسى .پۈتۈن ساننى چىقىرىپ بىرىدۇ.
(9) . LEN فونكىسيەسى . بىر ھەرپ تىزمىسىنىڭ ئۇزۇنلۇقىنى تىپىش فونكىيەسى.
(10) . YEAR فونكىسيەسى. يىل سانىنى تىپىش فونكىسيەسى.
(11) . TRUNC فونكىسيەسى. بۇ فونكىسيە كەسىر چىكىتى كەينىدىكى سانلارنى تاشلىۋىتىدۇ.
(12). DATEDIF فونكىسيەسى . ئىككى چىسلا ئارىسىدىكى پەرقنى تىپىپ چىقىدۇ.
مەنبە تور

Intil · ۋاقتى: 2011-5-9 01:49:25

مۆچەلنى تېپىش

=MID("鼠牛虎兔龙蛇马羊猴鸡狗猪",MOD(YEAR(D2)-4,12)+1,1)

مەزمۇننى كۆچۈرۈۋېلىش

كىملىك نومۇرى توغرىمۇ؟

=OR(LEN(B2)=15,IF(LEN(B2)=18,MID("10X98765432",MOD(SUM(MID(B2,ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1)=RIGHT(B2)))

مەزمۇننى كۆچۈرۈۋېلىش

تۇرۇشلۇق شەھەر

=IF(B2<>"",VLOOKUP(LEFT(B2,2),地址码!B:C,2,),)

مەزمۇننى كۆچۈرۈۋېلىش

تۇرۇشلۇق رايۇن

=IF(B2<>"",VLOOKUP(LEFT(B2,6),地址码!B:C,2,),)

مەزمۇننى كۆچۈرۈۋېلىش

تۇغۇلغان ۋاقتىدىن يۇلتۇز تۈركۈمىگە ھۆكۈم قىلىش

=LOOKUP(--TEXT($D2,"m.dd"),{0,"魔羯座 Capricorn";1.2,"水瓶座 Aquarius";2.19,"雙魚座 Pisces";3.21,"牡羊座 Aries";4.2,"金牛座 Taurus";5.21,"雙子座 Gemini";6.22,"巨蟹座 Cancer";7.23,"獅子座 Leo";8.23,"處女座 Virgo";9.23,"天秤座 Libra";10.24,"天蠍座 Scorpio";11.23,"射手座 Sagittarius";12.22,"魔羯座 Capricorn"})

مەزمۇننى كۆچۈرۈۋېلىش

تۇغۇلغان كۈنى ھەپتىنىڭ قايسى كۈنى؟

=LOOKUP(--TEXT($D2,"m.dd"),{0,"星期五";1.2,"星期六";2.19,"星期二";3.21,"星期二";4.2,"星期天";5.21,"星期三";6.22,"星期四";7.23,"星期三";8.23,"星期五";9.23,"星期四";10.24,"星期五";11.23,"星期一";12.22,"星期五"})

مەزمۇننى كۆچۈرۈۋېلىش

ئەسكەرتىش: يۇقارقى فورمۇلانى بىۋاستە كىرگۈزسىڭىزلا ئىشلىمەسلىكى ئېنىق، بۇنىڭ ئۈچۈن فورمۇلادا نەقىللەنگەن بىر قىسىم ئۇچۇرلارنى مەلۇم جەدۋەلدە تەييارلىۋېلىشىڭىز كېرەك.

Intil · ۋاقتى: 2011-6-16 15:36:34

كىملىك نومۇرىغا ئاساسەن تۇغۇلغان ۋاقتىنى ۋە جىنسىنى ھاسىللاش، ياش ھېساپلاش

=IF(LEN(A7)=18,DATEDIF(TEXT(MID(A7,LEN(A7)/2-2,8),"0-00-00"),"2011-12-31","Y"),DATEDIF(TEXT(19&MID(A7,LEN(A7)/2,6),"0-00-00"),"2011-12-31","Y"))

مەزمۇننى كۆچۈرۈۋېلىش

ياكى

=DATEDIF(TEXT(MID(A7,7,8),"0000-00-00"),TODAY(),"y")

مەزمۇننى كۆچۈرۈۋېلىش

A1 دە تېكىست شەكلىدە 18 خانىلىق كىملىك نومۇرى بار بولسا B1 گە بۇنى كىرگۈزسىڭىز تۇغۇلغىنىغا قانچە ياش، قانچە ئاي، قانچە كۈن بولغىنىنى چىقىرىدۇ.

=YEAR(TODAY()-DATE(MID(A1,7,4),MID(A1,11,2),MID(A1,13,2)))-1900&"岁"&MONTH(TODAY()-DATE(MID(A1,7,4),MID(A1,11,2),MID(A1,13,2)))-1&"月"&DAY(TODAY()-DATE(MID(A1,7,4),MID(A1,11,2),MID(A1,13,2)))&"天"

مەزمۇننى كۆچۈرۈۋېلىش

A1 دە تېكىست شەكلىدە 18 خانىلىق كىملىك نومۇرى بار بولسا B1 دە چېسلا بولسا ، C1 گە بۇنى كىرگۈزسىڭىز تۇغۇلغىنىغا قانچە ياش، قانچە ئاي، قانچە كۈن بولغىنىنى چىقىرىدۇ.

=YEAR(B1-DATE(MID(A1,7,4),MID(A1,11,2),MID(A1,13,2)))-1900&"岁"&MONTH(B1-DATE(MID(A1,7,4),MID(A1,11,2),MID(A1,13,2)))-1&"月"&DAY(B1-DATE(MID(A1,7,4),MID(A1,11,2),MID(A1,13,2)))&"天"

مەزمۇننى كۆچۈرۈۋېلىش

bahwan44 · ۋاقتى: 2011-8-4 14:33:53

مەن ئۇزۇندىن بىرى مۇشۇنداق ياش ھىساپلاش ، چوڭ ـ كىچىكلىكىنى ئايرىش دىگەندەك ئۇچۇرلارنى ئىزدەپ يۇرەتتىم . كۆپ رەخمەت سىزگە!

kubas · ۋاقتى: 2011-9-15 15:13:04

rahmat sizga intil apandi man koqurwaldim

Intil · ۋاقتى: 2011-12-21 23:36:41

D2 دىكى تۇغۇمغان ۋاقتىدىن مۆچەلنى تېپىش

=MID("鼠牛虎兔龙蛇马羊猴鸡狗猪",MOD(YEAR(D2)-4,12)+1,1)

مەزمۇننى كۆچۈرۈۋېلىش

D2 دىكى تۇغۇمغان ۋاقتىدىن يۇلتۇز تۈركۈمىنى تېپىش

=LOOKUP(--TEXT($D2,"m.dd"),{0,"魔羯座 Capricorn";1.2,"水瓶座 Aquarius";2.19,"雙魚座 Pisces";3.21,"牡羊座 Aries";4.2,"金牛座 Taurus";5.21,"雙子座 Gemini";6.22,"巨蟹座 Cancer";7.23,"獅子座 Leo";8.23,"處女座 Virgo";9.23,"天秤座 Libra";10.24,"天蠍座 Scorpio";11.23,"射手座 Sagittarius";12.22,"魔羯座 Capricorn"})

مەزمۇننى كۆچۈرۈۋېلىش

دىققەت: ctrl+shift+enter
D2 دىكى تۇغۇمغان ۋاقتىدىن سەپتىنىڭ كۈنىنى تېپىش

=LOOKUP(--TEXT($D2,"m.dd"),{0,"星期五";1.2,"星期六";2.19,"星期二";3.21,"星期二";4.2,"星期天";5.21,"星期三";6.22,"星期四";7.23,"星期三";8.23,"星期五";9.23,"星期四";10.24,"星期五";11.23,"星期一";12.22,"星期五"})

مەزمۇننى كۆچۈرۈۋېلىش

Intil · ۋاقتى: 2011-12-21 23:39:25

كىملىكنىڭ تەۋە رايۇنىنى تېپىش

=IF(B2<>"",VLOOKUP(LEFT(B2,2),地址码!B:C,2,),)

مەزمۇننى كۆچۈرۈۋېلىش

بۇنىڭدىكى 地址码!B:C نىڭ مەنىسى: 地址码 ناملىق جەدۋەلدىكى B دا تەۋە رايۇن نومۇرى C دا رايۇن نامى بار.
B2 دە كىملىك نومۇرى بار

bostan305 · ۋاقتى: 2012-1-6 17:56:22

مەن مۇشۇ فورمىلالارنى تاپالماي قالغانتىم، ھازىرلا ھەممىسىنى ساقلىۋالاي جۇمۇ

ھېسابات		ساقلاش	پارول قايتۇرىۋېلىش
پارول			تىزىملىتىش

مىكروبلوگ[ يېڭى | 24 سائەت | 7 كۈن | 30 كۈن ]

excel دا كىملىك نومۇرىغا ئائىت فۇنكسىيە جەۋھىرى

باھا سۆز

مۇناسىۋەتلىك تېمىلار